restart;

unassign('deq', 'rec'):

interface(elisiondigitsthreshold=100, elisiondigitsbefore=10, elisiondigitsafter=10):

gfun

with(gfun):

deq[arctan] := holexprtodiffeq(arctan(z), y(z));

deq[arctan] := diffeqtohomdiffeq(deq[arctan], y(z));

deq[Ai] := holexprtodiffeq(AiryAi(z), y(z));

ordeq := 4: degcoeff := 3:

deq[random] := { add( RandomTools[Generate]( polynom(rational(denominator=24), z, degree=degcoeff)) * diff(y(z),[z$k]), k=0..4), seq( (D@@k)(y)(0) = RandomTools[Generate]( rational(denominator=24)), k=0..ordeq-1)};

`diffeq+diffeq`(deq[arctan], deq[Ai], y(z));

rec[Ai] := diffeqtorec(deq[Ai], y(z), u(n));

coeffproc[Ai] := rectoproc(rec[Ai], u(n)):

coeffproc[Ai](50001);

NumGfun : \303\251valuation

with(NumGfun);

Suites d'entiers (combinatoire...)

rec[Catalan] := {C(n+1)=(4*n+2)/(n+2)*C(n),C(0)=1};

nth_term(rec[Catalan], C(n), 50000);

Pi par la formule des Chudnovsky

A, B, C := 13591409, 545140134, 640320^3;

rec[Pi] := {(A+B*n)*(3*n+3)*(3*n+2)*(3*n+1)*(n+1)^3*C * u(n+1) + (6*n+6)*(6*n+5)*(6*n+4)*(6*n+3)*(6*n+2)*(6*n+1)*(A+B*(n+1)) * u(n), u(0) = 12*A };

x := fnth_term(rec[Pi], u(n), 1000, 10001, 'series');

evalf[10001](sqrt(C)/x);

arctangente

deq[arctan];

evaldiffeq(deq[arctan], y(z), 1/2, 50);

evaldiffeq(deq[arctan], y(z), (1+I)/2, 5000);

baredeq := op(1, deq[arctan]);

evaldiffeq(baredeq, y(z), (1+I)/2, 50);

transition_matrix(baredeq, y(z), 1/2, 20);

evaldiffeq(deq[arctan], y(z), 2, 50);

evaldiffeq(deq[arctan], y(z), [2], 50);

evaldiffeq(deq[arctan], y(z), [1+I], 50);

transition_matrix(deq[arctan], y(z), [0,I+1,2*I,I-1,0], 15);

Une fonction de Heun

alpha := 1: beta := 1/3: Gamma := 1/2: delta := 3:

deq[Heun] := {diff(y(z), z, z)-(-2*z^5+4*z^3+z^4*alpha-2*z-alpha)*(diff(y(z), z))/((z-1)^3*(z+1)^3)-(-z^2*beta+(-Gamma-2*alpha)*z-delta)*y(z)/((z-1)^3*(z+1)^3), y(0)=1, D(y)(0)=0};

evalf[51](HeunD(alpha, beta, Gamma, delta, 1/2));

evalf(HeunD(alpha, beta, Gamma, delta, -0.9));

evalf(HeunD(alpha, beta, Gamma, delta, -0.99));

myHeunD := diffeqtoproc(deq[Heun], y(z)):

myHeunD(1/2, 50);

myHeunD(-0.9, 9);

myHeunD(-0.99, 200);

deq[random];

sing := NumGfun:-diffeq_singularities(deq[random], y(z)); plots[complexplot](sing, style=point, symbolsize=50);

evaldiffeq(deq[random], y(z), [0.737*I], 30);

evaldiffeq(deq[random], y(z), evalf[1000](1/Pi), 1000);

NumGfun : bornes symboliques

R\303\251currences

rec[fac] := {(2*n+2)^2*u(n+1) = -(n+1)*u(n), u(0) = 1};

bound_rec(rec[fac], u(n));

rec[cstcoeff] := {4*u(n+1)-13*u(n+2)+5*u(n+3), u(0) = 17/5, u(1) = 3, u(2) = 3/12, u(3) = 0, u(4) = 5};

bound_rec(rec[cstcoeff], u(n));

\303\211quations diff\303\251rentielles

bound_diffeq({diff(y(z), z) = y(z), y(0) = 1}, y(z));

bound_diffeq(deq[arctan], y(z));

bound_diffeq(deq[random], y(z));

bound_diffeq(y(z) = (z^7+3*z^2+z+1)/((z-2)^3*(z^3-3)*(z-I)^2), y(z));

bound_diffeq_tail(deq[arctan], y(z), n);

asympt(AiryBi(z), z,1);

bound_diffeq_tail(deq[Ai], y(z), 0);

Contr\303\264le d'erreur et subdivision des chemins

forget(NumGfun);

infolevel[gfun] := 3;

evaldiffeq(deq[arctan], y(z), 1/4, 100);

infolevel[gfun] := 2;

evaldiffeq(deq[arctan], y(z), [1-I,2*I], 100);